Competition for Territory: The Levins Model for Two Species

Manipulate[
If[Abs[k1-e1]<0.0001,k1=.01];
If[Abs[k2-e2]<0.0001,k2=.01];
If[Abs[e1-e2]<0.0001,e1=.01];
Module[{eqn,p1,p2,equilib},

eqn:={{p1*(k1*(1 - p1-p2) - e1),p2*(k2*(1 - p1 - p2) - e2 )},{p1 (k1 (1-p1)-e1),p2 (k2 (1-p1-p2)-e2-k1 p1)},
{p1 (k1 (1-p1-p2)-e1+c p2),p2 (k2 (1-p2-p1)-e2-c p1)}};
kk1:=Which[q===0,0,q===1,k1, True,1];
kk2:=Which[q===0,0,q===1,-k1, True,1];
equilib:=Map[
Cases[#,{u_,v_}/;(u≥-10^(-10.))&& (v≥-10^(-10.))&& (u+v≤1)]&,{p1,p2}/.Map[Quiet@Solve[#=={0,0},{p1,p2}]&,eqn]];
Pane[
Grid[{{
LocatorPane[Dynamic[IC],
Dynamic[Show[
Graphics[
{Black,PointSize[0.02],Point[Map[RegionLoc,IC]],Blue,Point[equilib[[q+1]]]}],
StreamPlot[eqn[[q+1]],{p1,0,1.},{p2,0,1.},StreamPoints->{Map[RegionLoc,IC],Automatic,{Forward,T}},StreamColorFunction->Hue,StreamStyle->{Thickness[0.01],"Line"}],
StreamPlot[eqn[[q+1]],{p1,0,1.},{p2,0,1.},RegionFunction->((#1+#2)<1&),Axes->True,AxesLabel->{"p1","p2"},StreamScale->Large,StreamStyle->{Directive[{Thickness[0.005],Hue[0.7,0.2,0.7,0.4]}]}]
,AspectRatio->Automatic,PlotRange->{{0,1},{0,1}},Axes->True,AxesLabel->{"(Subscript[p, 1])","(Subscript[p, 2])"},ImageSize->{275,275}]]
,Appearance->None,LocatorAutoCreate->True],
Text@Column[Prepend[equilib[[q+1]],"equilibria: \n"],ItemSize->{6,Automatic}]}}],
{400,350},Alignment->Center]
],
{kk1,ControlType->None},
{kk2,ControlType->None},
{{q,0,"colonization strategies"},{0->"\!\(\*SubscriptBox[\(p\), \(\(1\)\(\\ \)\)]\)⥯ (Subscript[p, 2])",1->"(Subscript[p, 1])⟶(Subscript[p, 2])",2->"\!\(\*SubsuperscriptBox[SubscriptBox[\(p\), \(\(1\)\(\\ \)\)], \(⟵\), \(⟶\)]\) (Subscript[p, 2])"},RadioButtonBar,ImageSize->Tiny,ControlPlacement->Top},
Style["species 1 rates",Bold],
{{k1,0.7,"colonization"},0,1,.01,Appearance->"Labeled",ImageSize->Tiny}
,{{e1,0.5,"extinction"},0,1,.01,Appearance->"Labeled",ImageSize->Tiny}, Delimiter
,Style["species 2 rates",Bold]
,{{k2,0.7,"colonization"},0,1,.01,Appearance->"Labeled",ImageSize->Tiny}
,{{e2,0.1,"extinction"},0,1,.01,Appearance->"Labeled",ImageSize->Tiny}
,Delimiter
,{{c,0,"relative \novercolonization"},-kk2,kk1,ImageSize->Tiny},Delimiter,
{{T,0.6},0.01,1.5,0.01,Appearance->"Labeled",ImageSize->Tiny},
Delimiter,
Style["initial conditions",Bold],
{{IC,{{0.8,0.1},{0.1,0.8}},""},Button["reset locators",IC={{0.8,0.1},{0.1,0.8}}]&},ControlPlacement->Left,
AutorunSequencing->{3,4,5},
Initialization:>
{
RegionLoc[p_?VectorQ]:={Max[p[[1]],0],Min[Max[p[[2]],0],1-Max[p[[1]],0]]};
}
]

CAPTION

This population dynamics model (being the extension of the well-known Levins metapopulation model) describes the competition for territory of two species having different colonization strategies. The model equations are:

(Subscript[p, 1])'(t) =(Subscript[c, 1])(Subscript[p, 1])(t)(1-(Subscript[p, 1])(t)-(Subscript[p, 2])(t))-(Subscript[e, 1])(Subscript[p, 1])(t) + o (Subscript[p, 1])(t)(Subscript[p, 2])(t),(Subscript[p, 2])'(t) = (Subscript[c, 2 ])(Subscript[p, 2])(t)(1-(Subscript[p, 1])(t)-(Subscript[p, 2])(t))-(Subscript[e, 2]) (Subscript[p, 2])(t) - o (Subscript[p, 1])(t)(Subscript[p, 2])(t),

where (Subscript[p, 1])(t) and (Subscript[p, 2])(t) are the portion of the territory at time t occupied by species 1 and 2, respectively. The occupation is exclusive. Hence, the assumptions 0≤(Subscript[p, 1])(t),0≤(Subscript[p, 2])(t) and (Subscript[p, 1])(t)+(Subscript[p, 2])(t)≤1 hold.

The meaning of the parameters is as follows:

(Subscript[c, 1]), (Subscript[c, 2])≥0, the global rates of colonization, describe how the species can colonize empty patches. The global rates of extinction are (Subscript[e, 1]), (Subscript[e, 2])≥0. The global rate of relative overcolonization o describes how the species can occupy the patches occupied by the other species.

DETAILS

In general, overcolonization is the phenomenon of a certain species occupying territories already being occupied by other species. In the case of preemptive competition there is no interaction between the species; they can occupy only empty patches. In the case of hierarchical relationship, species 1 can occupy both empty patches and those that are occupied by species 2. Species 2 can colonize only empty patches. In general cases of overcolonization both species can colonize both empty and occupied patches.

In our model, these cases are represented as follows:

(Subscript[p, 1 ])⥯ (Subscript[p, 2]):  o=0—no overcolonization, preemptive model.

(Subscript[p, 1])⟶(Subscript[p, 2]): o=(Subscript[k, 1])—species 1 can occupy the empty territories of species 2.

(Subscript[p, 2])⟶(Subscript[p, 1]): o=-(Subscript[k, 2])—species 2 can occupy the empty territories of species 1.

(Subscript[(Subscript[p, 1 ]), ⟵]^⟶) (Subscript[p, 2]): o>0—species 1 is stronger; it can occupy more of species 2's territories than species 2 can occupy of species 1's territories. o<0 gives the opposite case.

Besides the trivial equilibrium, there are always two more equilibria, where one of the variables is zero and the other is positive. One can observe that no coexistence of species is possible if no interaction is allowed. The positive asymptotically stable equilibrium can exist only if there is some kind of interaction between the species.

The equilibria of the preemptive competition are (0, 0), (1-((Subscript[e, 1])/(Subscript[c, 1])),0) and (0,1-((Subscript[e, 2])/(Subscript[c, 2]))).

The equilibria of the hierarchical overcolonization model are (0, 0), (1-((Subscript[e, 1])/(Subscript[c, 1])),0), (0,1-((Subscript[e, 2])/(Subscript[c, 2]))) and (((-(Subscript[c, 1])((Subscript[e, 2])+(Subscript[c, 1]))+(Subscript[e, 1])((Subscript[c, 1])+(Subscript[c, 2])))/((Subscript[c, 1])(Subscript[c, 2]))),1-((Subscript[e, 1])/(Subscript[c, 1]))).

The equilibria of the general overcolonization model are (0, 0), (1-((Subscript[e, 1])/(Subscript[c, 1])),0), (0,1-((Subscript[e, 2])/(Subscript[c, 2]))) and ((((Subscript[e, 2])(Subscript[c, 1])-(Subscript[e, 1])(Subscript[c, 2])+ o (-(Subscript[e, 2])+(Subscript[c, 2])))/(o(o-(Subscript[c, 1])+(Subscript[c, 2])))), ((c ((Subscript[e, 1])-(Subscript[c, 1]))-(Subscript[e, 2])(Subscript[c, 1])+(Subscript[e, 1])(Subscript[c, 2]))/(o(o-(Subscript[c, 1])+(Subscript[c, 2]))))).

In practice, weeds are very aggressive in colonization and their extinction can be very low. Other species like pine or oak colonies can colonize slowly but their extinction is also low.

References:

I. Szimjanovszki, "Computer-Aided Analysis of the Growth of the Territory-Occupational Populations Using Mathematica," master's thesis, 2008.

E. V. P. Racz and J. Karsai, "Computer Simulation Results for Cellular Automata Models of Some Ecological Systems," Folia FSN Universitatis Masarykianae Brunensis, Mathematica, 13, 2003b pp. 213–221.

THIS NOTEBOOK IS THE SOURCE CODE FROM

"Competition for Territory: The Levins Model for Two Species" from the Wolfram Demonstrations Project
 http://demonstrations.wolfram.com/CompetitionForTerritoryTheLevinsModelForTwoSpecies/

Contributed by: Irma Szimjanovszki, Janos Karsai (University of Szeged, Hungary), and Eva Veronika Racz (Szechenyi Istvan University, Gyor, Hungary)

A full-function Wolfram Mathematica system (Version 6 or higher) is required to edit this notebook.
GET WOLFRAM MATHEMATICA »

© Wolfram Demonstrations Project & Contributors   |   Terms of Use   |   Make a new version of this Demonstration »